I have made slight modifications to keep the loop part clean and instead added your re-advertising routine to the disconnect callback. The entire example code is below at the end of this post.

I will also update the BasicBLE example. Thank you.

Yes, iOS somewhat limits the flexibility in app development. Of course, Android also enforces some changes with every new API release / update, but I don't need to buy a new PC for this
This is just my first impression - I have never really done any iOS development...

P.S.: The app price on Android is around 10$. I understand there is a big market for iOS, especially in the US. The logical step would be to support this, but I currently develop the app alone and also take care of the examples, the website, the designer tool etc... Frankly, porting to iOS scares me a bit... It is going to take some time and a fair amount of energy

BR,
kl3m3n

/*
 * GUI-O Basic BLE example (using ESP32-WROOM-32)
 *
 * Copyright (C) 2021, GUI-O Team
 *
 * SPDX-License-Identifier: BSD-3-Clause
 */

#include <BLEDevice.h>
#include <BLEServer.h>
#include <BLEUtils.h>
#include <BLE2902.h>

namespace led {
  static const uint8_t LED_BUILTIN = 2;
  static const uint8_t LED_CHANNEL = 0;
  static const double LED_FREQ = 5000.0;
  static const uint8_t LED_BITS = 8;
} // namespace led

namespace uuid {
  static const char *SERVICE_UUID = "6E400001-B5A3-F393-E0A9-E50E24DCCA9E";
  static const char *RX_CHARACTERISTIC_UUID = "6E400002-B5A3-F393-E0A9-E50E24DCCA9E";
  static const char *TX_CHARACTERISTIC_UUID = "6E400003-B5A3-F393-E0A9-E50E24DCCA9E";
} // namespace uuid

// forward declare parser for incoming messages
void parseGuioMsg(const String &msg);

// setup done flag
bool setupDone = false;

// custom handling of server callbacks
class CustomBLEServerCallbacks: public BLEServerCallbacks {
    void onConnect(BLEServer* pServer) {
      Serial.println("Connected!");
    };
    void onDisconnect(BLEServer* pServer) {
      Serial.println("Disconnected!");

      // fix provided by BM
      // restart advertising after disconnect, otherwise GUI-O cannot re-connect
      if(setupDone) {
        // restart advertising on disconnect
        delay(500);
        pServer->startAdvertising(); 
      }
    }
};

// custom handling of characteristic callbacks
class CustomBLECharacteristicCallbacks: public BLECharacteristicCallbacks {
  void onWrite(BLECharacteristic *pCharacteristic) {
    std::string msg = pCharacteristic->getValue();
    
    // parse message string
    parseGuioMsg(String(msg.c_str()));
  }      
};

// global ptr
BLECharacteristic *pTxCharacteristic;

void setup() {
  // debug output
  Serial.begin(115200);

  // setup builtin led
  ledcSetup(led::LED_CHANNEL, led::LED_FREQ, led::LED_BITS); // channel, freq, resolution_bits
  ledcAttachPin(led::LED_BUILTIN, led::LED_CHANNEL);

  // create device
  BLEDevice::init("BasicBLE_NUS");
  // create server and register callback
  BLEServer *pServer = BLEDevice::createServer();
  pServer->setCallbacks(new CustomBLEServerCallbacks());
  // create service
  BLEService *pService = pServer->createService(uuid::SERVICE_UUID);

  // crate Tx characteristic and add descriptor
  pTxCharacteristic = pService->createCharacteristic(uuid::TX_CHARACTERISTIC_UUID, BLECharacteristic::PROPERTY_NOTIFY);
  pTxCharacteristic->addDescriptor(new BLE2902());
  
  // crate Rx characteristic and register callback
  BLECharacteristic *pRxCharacteristic = pService->createCharacteristic(uuid::RX_CHARACTERISTIC_UUID, BLECharacteristic::PROPERTY_WRITE | BLECharacteristic::PROPERTY_WRITE_NR);
  pRxCharacteristic->setCallbacks(new CustomBLECharacteristicCallbacks());

  // start the service and start advertising
  pService->start();
  pServer->getAdvertising()->start();

  // setup done flag
  setupDone = true;
}

void loop() {
  
}

/***************************/
/* IMPLEMENT YOUR GUI HERE */
/***************************/
void sendMsg(const String &msg) {
  pTxCharacteristic->setValue(std::string(msg.c_str()));
  pTxCharacteristic->notify();
  delay(50);
}

void parseGuioMsg(const String &msg) {
  if(msg.startsWith("@init")) {
    Serial.println("GUI-O app is requesting INITIALIZATION!");

    // clear screen and set background
    sendMsg("@cls\r\n");
    sendMsg("@guis BGC:#FFFFFF\r\n");
    delay(100);

    // initialize simple example GUI
    sendMsg("|LB UID:title X:50 Y:15 TXT:\"Simple light switch\" FFA:\"font8\" FSZ:3.5\r\n");
    sendMsg("|LB UID:tap_me X:50 Y:70 TXT:\"TAP ME!\" FFA:\"font8\" FSZ:3 FFA:\"font5\"\r\n");
    sendMsg("|CB UID:brightness X:50 Y:50 W:90 BTH:5 HAH:8 HAW:8 VIS:0 STA:135 ENA:45 FGC:#000000 SFGC:#FFFF00 BGC:#CBCBCB\r\n");
    sendMsg("|IM UID:light_off X:50 Y:50 IP:\"https://i.imgur.com/3VbsS0Z.png\" VIS:1\r\n");
    sendMsg("|IM UID:light_on X:50 Y:50 IP:\"https://i.imgur.com/gNdck9A.png\" VIS:0\r\n");    
  }
  else if(msg.startsWith("@light_off")) {
    Serial.println("GUI-O app is requesting LIGHT ON!");

    // "drive GUI-O app"
    sendMsg("@light_off VIS:0\r\n");
    sendMsg("@light_on VIS:1\r\n");
    sendMsg("@brightness VIS:1 VAL:100\r\n");

    // led enable
    ledcWrite(led::LED_CHANNEL, 255);
  }
  else if(msg.startsWith("@light_on")) {
    Serial.println("GUI-O app is requesting LIGHT OFF!");

    // "drive GUI-O app"
    sendMsg("@light_off VIS:1\r\n");
    sendMsg("@light_on VIS:0\r\n");
    sendMsg("@brightness VIS:0 VAL:0\r\n");

    // led disable
    ledcWrite(led::LED_CHANNEL, 0);
  }
  else if(msg.startsWith("@brightness")) {
    const int idx = msg.indexOf(' ');
    
    if(idx > 0) {
      const int val = msg.substring(idx + 1).toInt();
      
      if(val >= 0 && val <= 100) {
        Serial.print("GUI-O app is requesting LIGHT BRIGHTNESS: ");
        Serial.println(val);

        // led drive
        ledcWrite(led::LED_CHANNEL, static_cast<uint8_t>(val * 2.55));
      }            
    }    
  }  
}

That is great news! I would be much obliged to see the modified code - I can then update the BLE examples. I would like add you as a contributor (bmiller) at the start of the example code, if it is OK with you? You can post the code patch here (just the changes) or send it to info.guio.app[at]gmail.com.

Regarding iOS - I know that in USA there are more iOS users and porting GUI-O to iOS would indeed reach a broader audience. The porting process would probably not be too difficult as most of the GUI-O source is in C++ (and I think that clang compiler allows mixing C++ with objective C code). But it is very difficult to set up an effective development environment without using a mac - and boy, are this devices expensive...

It would be awesome if the income from the GUI-O app could cover such expenses in the future. So, my reply would be - iOS is planned, but the time-frame is undetermined.

BR,
kl3m3n

BR

@bmillier said in How does GUI-O's auto-connect work in BLE?:

I know the ESP32 caches WiFi SSIDs, etc. but wonder if it stores BLE characteristics in non-volatile Flash too?

Can you try unpairing the ESP32 from the Android system Bluetooth menu (under settings -> Bluetooth)? It seems that you Android device has cached the "old" pairing data. Maybe this will help.

@bmillier said in How does GUI-O's auto-connect work in BLE?:

Sorry for all this trouble- I'm doing fine with legacy Bluetooth, so the BLE is not a deal-breaker for me- except that I can't use my ESP32-S3 which only has BLE.

I think that the ESP32-S3 also has WiFi? You could try the "IoT" examples? Everything is basically the same, but over WiFi (or mobile data from the Android side). "IoT" is based on MQTT protocol.

BR,
kl3m3n

Looking at your BLE_NUS code, I cannot figure out where all of the above services/characteristics are coming from. It seems the FFE0/FFE1 values are "left over" from the BasicBLE.ino program I had tried before. I know the ESP32 caches WiFi SSIDs, etc. but wonder if it stores BLE characteristics in non-volatile Flash too?
I am wondering if this problem arises from my Android tablet, and not GUI-O code? It is an older Samsung Galaxy Tab 10.1 which I had to root and then install Lineage 16 Android OS. My wife has a much newer LG Android smartphone, but currently I only have GUI-O licensed for the Note 10.1
Sorry for all this trouble- I'm doing fine with legacy Bluetooth, so the BLE is not a deal-breaker for me- except that I can't use my ESP32-S3 which only has BLE.
BR

@bmillier said in How does GUI-O's auto-connect work in BLE?:

On a happier note, I submitted my article to SE with a GUI-O project and they are processing it now. Also, another, more complex project that I am doing using GUI-O + legacy Bluetooth is working well, at this stage anyway. That project is for Circuit Cellar, but will be a ways off.

Wow, this is very nice to hear!

Regarding the BLE troubles - I will dive deeper and try to figure out what's wrong...

Since the service service and characteristic UUIDs are not standardized, I have made this user-selectable. But, if you don't want to go through this selection procedure, use NUS (Nordic UART service) UUIDs. Check out the code here BasicBLE_NUS.ino.

This basically sets a standardized service and characteristic UUID that GUI-O recognizes and connects to automatically. So, everything is the same as in the other example, just the values are different:

...SERVICE_UUID = "6E400001-B5A3-F393-E0A9-E50E24DCCA9E";
...RX_CHARACTERISTIC_UUID = "6E400002-B5A3-F393-E0A9-E50E24DCCA9E";
...TX_CHARACTERISTIC_UUID = "6E400003-B5A3-F393-E0A9-E50E24DCCA9E";

I could of course add support for "GUI-O UART service" in the same way.

BR,
kl3m3n

the BLE example seem to work okayish for me (using ESP32-WROOM-32)... I can connect immediately and the communication works.

But, if I quit the GUI-O app during the connection and re-open it, the connection cannot be established - I get an error if I wait... But (again ), if I reset the ESP32-WROOM-32 board during this connection procedure, everything works OK.

Do you experience similar symptoms? I will make a video of this and post it here for reference (hopefully tomorrow). What happens if you reset the ESP32 board when the connection process is taking too long? Can you please try this?

BR,
kl3m3n

Thank you for the feedback.

BR,
kl3m3n